ActionScript Instances

Summary:

How to...

ActionScript Instances

hartnell 11 Sep 2007 06:48

How do you create an instance of an object using ActionScript during runtime? How do you destroy it? Think bullets. :)

—hartnell

Re: ActionScript Instances

Linkage2 11 Sep 2007 07:45

That's actually something I'm trying to get my head around right now, but in the sense of finding a good way to lay out a level for a platform style and then being able to do collision detection with it.

Well, I think before you get going with your code, you should first attach a Bullet Movie Clip, like so:

this.attachMovie("bullet","bullet",1);

The first parameter is the Linkage (hehe) name for the Movie Clip, I'm assuming you'd set it to something like bullet. The second parameter is the new name for the object, and the third is its depth- note that when you make a new object on the same depth as another object, it will overwrite any previous on that depth.

Then, whenever you need to spawn a bullet, just do this:

bullet.duplicateMovieClip(<new name>, <depth>);
<new name>._x = wherever you want it go, same for _y.

A good way to keep everything on different depths is to, assuming you're finding the bullet you want with a for loop + check for use, set its depth to the current value for your for variable (I usually use g for for loops).

Duplicating clips and then checking collision for each of them is where I'm stuck. I don't know how to reference each one correctly.

Re: ActionScript Instances

hartnell 12 Sep 2007 02:26

Ok, let me try to understand this. Even though you have the movie clip as an asset, you have to "attach" it as an asset?

—hartnell

Re: ActionScript Instances

Woad 11 Sep 2007 23:10

No, that's a stupid way to do it i'm afraid to say.
First you'll run into a depth problem very quickly, if you just use a for variable (like i or j) then when you try to make more it will take those depths and destroy any movieclip that was using it.
Also, there's no need to do attach in the beggining and then duplicate the movie everytime, just attach everytime.
Here's an example that will hopefully help you out.

Shoot = function()
{
mc = _root.attachMovie("bullet","bullet"+_root.getNextHighestDepth(),_root.getNextHighestDepth());
mc._x = player._x;
mc._y = player._y;
mc.dir = Math.atan2(_ymouse -mc._y,_xmouse - mc._x);
mc.speed = 5;
mc.onEnterFrame = function()
{
this._x += Math.cos(this.dir)*this.speed;
this._y += Math.sin(this.dir)*this.speed;
if(this._x < 0 || this._x > Stage.width || this._y < 0 || this._y > Stage.height)
{
this.removeMovieClip();
}
//Collision if statements
if(this.hitTest(_root.target)) //Make a target movieclip, give it an instance name of target and put it on the stage.
{
this.removeMovieClip();
}
}
}
onMouseDown = function()
{
Shoot();
}
player.onEnterFrame = function()
{
if(Key.isDown(Key.LEFT))
{
this._x -= 3;
}
if(Key.isDown(Key.RIGHT))
{
this._x += 3;
}
if(Key.isDown(Key.UP))
{
this._y -= 3;
}
if(Key.isDown(Key.DOWN))
{
this._y += 3;
}
}

You also need to place a player movieclip onto the stage with an instance name of player.

Does that clear anything up?

Last edited on 11 Sep 2007 23:12 by Woad Show more

Re: ActionScript Instances

Linkage2 12 Sep 2007 06:43

Yeah, that helps. I'm not surprised I was doing it wrong, I don't really have my head around the way AS wants to be treated just yet.